ページ取得メソッド

$mech->get($url)
$mech->reload()
$mech->back()

リンク追跡メソッド

$mech->follow_link(...)

フォームフィールド入力メソッド

$mech->form_number($number)
$mech->form_name($name)
$mech->field( $name, $value, $number )
$mech->field( $name, \@values, $number )
$mech->set_fields( $name => $value ... )
$mech->set_visible( @criteria )
$mech->tick( $name, $value [, $set] )
$mech->untick($name, $value)

フォーム送信メソッド

$mech->click( $button [, $x, $y] )
$mech->click_button( ... )
$mech->select($name, $value)
$mech->select($name, \@values)
$mech->submit()
$mech->submit_form( ... )

ステータスメソッド

$mech->success()
$mech->uri()
$mech->response() / $mech->res()
$mech->status()
$mech->ct()
$mech->base()
$mech->content()
$mech->forms()
$mech->current_form()
$mech->links()
$mech->is_html()
$mech->title()

コンテントハンドリングメソッド

$mech->find_link()
$mech->find_link() : link format
$mech->find_all_links( ... )

その他のメソッド

$mech->add_header( name => $value [, name => $value... ] )
$mech->delete_header( name [, name ... ] )
$mech->quiet(true/false)

LWP::UserAgentメソッドのオーバーライド

$mech->redirect_ok()
$mech->request( $request [, $arg [, $size]])
$mech->update_html( $html )
$mech->_parse_html()
$mech->_modify_request( $req )
$mech->_make_request()

使用が推奨されないメソッド

$mech->follow($string|$num)
$mech->form($number|$name)

内部使用限定のメソッド

$mech->_reset_page()
$mech->_extract_links()
$mech->_push_page_stack() / $mech->_pop_page_stack()
warn( @messages )
die( @messages )

この他のドキュメント

Spidering Hacks, by Kevin Hemenway and Tara Calishain
Web上のリソース
その他のMechanizeを使用するモジュール

要望とバグ
Author

NAME

WWW::Mechanize - Perlオブジェクト中のハンディWebブラウザ

VERSION

Version 1.02

    $Header: /cvsroot/www-mechanize/www-mechanize/lib/WWW/Mechanize.pm,v 1.129 2004/04/10 05:30:10 petdance Exp $

SYNOPSIS

WWW::Mechanize、あるいは縮めてMechはWebサイトとのやりとりの自動化を助けます。これはリンク先やフォームデータの送信を含む、複数のページの取得をサポートします。取得したページはそれぞれ解析され、そのリンクやフォームが抽出されます。リンクやフォームを選択し、フォームを埋め、次のページを取得することが可能です。Mechは訪れたURLの履歴を保持しますので、これを問いあわせたり再訪することも可能です。

    use WWW::Mechanize;
    my $mech = WWW::Mechanize->new();

    $mech->get( $url );

    $mech->follow_link( n => 3 );
    $mech->follow_link( text_regex => qr/download this/i );
    $mech->follow_link( url => 'http://host.com/index.html' );

    $mech->submit_form(
        form_number => 3,
        fields      => {
            username    => 'yourname',
            password    => 'dummy',
        }
    );

    $mech->submit_form(
        form_name => 'search',
        fields    => { query  => 'pot of gold', },
        button    => 'Search Now'
    );

MechはWebアプリケーションのテストにも良くあいます。the Test::HTML::Lint manpage モジュールなど、Test::*の内の一つを使えば、取得したコンテンツをチェックし、testコールへの入力に使うことができます。

    use Test::More;
    like( $mech->content(), qr/$expected/, "Got expected content" );

ページ取得を行う度にそのURLはスタックに保持され、これを前後に移動することができます。

    $mech->back();

ページ取得の過程をよりうまくコントロールしようと思ったら、以下のメソッドを使うことができます。follow_linkとsubmit_formは、つまるところこれらの高レベルのラッパーです。

    $mech->follow( $link );
    $mech->find_link( n => $number );
    $mech->form_number( $number );
    $mech->form_name( $name );
    $mech->field( $name, $value );
    $mech->set_fields( %field_values );
    $mech->set_visible( @criteria );
    $mech->click( $button );

the WWW::Mechanize manpageはまさしくthe LWP::UserAgent manpageのサブクラスであり、 the LWP::UserAgent manpageのどのメソッドも利用可能です。

    $mech->add_header($name => $value);

重要なリンク

http://search.cpan.org/dist/WWW-Mechanize/

http://rt.cpan.org/NoAuth/Bugs.html

コンストラクタと開始

`new()`

WWW::Mechanizeの新規オブジェクトを生成し、返します。以下ではこのオブジェクトを'agent'と呼びます。

    my $mech = WWW::Mechanize->new()

WWW::Mechanizeのコンストラクタは、LWP::UserAgentのコンストラクタへのパラメータのうち2つを上書きします。

    agent => "WWW-Mechanize/#.##"
    cookie_jar => {}    # an empty, memory-only HTTP::Cookies object

コンストラクタにパラメータを渡すことで、この上書き値を変更することができます。以下のようになります:

    my $mech = WWW::Mechanize->new( agent=>"wonderbot 1.01" );

cookie jarでのオーバーヘッドを避けたい時や、botにcookieを受け入れさせたくない時は、明示的にこれを禁止します。こんな感じです:

    my $mech = WWW::Mechanize->new( cookie_jar => undef );

以下はWWW::Mechanizeが認識できるパラメータです。これらはthe LWP::UserAgent manpageが認識するパラメータには含まれていません。

autocheck => [0|1]

onwarn => \&func()

Carp::carp

warn

ここにundefが設定されると、ワーニングはまったく表示されなくなります。とはいえ、その振る舞いを制御するのにquietを使うよりは良いでしょう。

この値が渡されなければ、MechはCarpがインストールされていれば Carp::carpを、そうでなければCORE::warnを使用します。

onerror => \&func()

Carp::croak

die

ここにundefが設定されると、エラーはまったく表示されなくなります。

この値が渡されなければ、MechはCarpがインストールされていれば Carp::croakを、そうでなければCORE::dieを使用します。

quiet => [0|1]

quiet => 1

$agent->quiet(1)

$mech->agent_alias( $alias )

実際にユーザーが渡した文字列からバージョンなどを拡張したものをuser agentに設定します。$aliasには以下のうち一つを使用できます。

Windows IE 6
Windows Mozilla
Mac Safari
Mac Mozilla
Linux Mozilla
Linux Konqueror

すると、最も関連深いものの一つに置き換えられます。例えば、

    $mech->agent_alias( 'Windows IE 6' );

ではUser-Agentは以下に設定されます。

    Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)

適切な別名の一覧はknown_agent_aliases()から返されます。

`known_agent_aliases()`

Mechが知っている全てのエージェントの別名のリストを返します。

ページ取得メソッド

$mech->`get($url)`

URL/URIを与えられると、それを取得します。the HTTP::Response manpage オブジェクトが帰り値です。$urlは適切に整形されたURL文字列か、 URIオブジェクトです。

この結果はagentオブジェクトに内部的に保持されますが、それを知っている必要はありません。以下にリストされているアクセッサを使うだけです。内部の詮索はしないように祈りますし、サブジェクトは将来変更されます。

get()はthe LWP::UserAgent manpageのメソッドをよりよい振る舞いをするようにオーバーライドしたバージョンです。これは

    $mech->get( $url, ":content_file"=>$tempfile );

のようなことを可能にしますし、このパラメータが適当にフィルタされて取得されることとみなして構いません。

$mech->`reload()`

ブラウザのリロードボタンのように振舞います: 現在のリクエストを再実行します。

リロードによるthe HTTP::Response manpageオブジェクトか、まだリクエストが実行されていない時は現在のリクエストがない時にはundefを返します。

$mech->`back()`

ブラウザの``back''ボタンを叩くのと等価です。前のページに戻ります。過去の最初のページに戻りたくはありませんか？（実際、それが可能だとしたらそうするでしょう？）

リンク追跡メソッド

$mech->`follow_link(...)`

そのページの指定されたリンクをたどります。find_link()で使うのと同じパラメータを使い、それにマッチするものを指定します。

以下がその例です:

``download''と名づけられた3番目のリンク

    $mech->follow_link( text => "download", n => 3 );

大文字小文字を区別せず、``download''をURL中に含む最初のリンク:

    $mech->follow_link( url_regex => qr/download/i );

または

    $mech->follow_link( url_regex => qr/(?i:download)/ );

ページ内の3番目のリンク

    $mech->follow_link( n => 3 );

リンクが見つかれば、GETメソッドの実行結果（HTTP::Response オブジェクト）が返されます。ページ内にリンクがないか、または指定されたリンクが見つからなかった時は、undefを返します。

このメソッドは、将来の開発では使用されない$mech->follow()の置き換えにあたります。

フォームフィールド入力メソッド

$mech->`form_number($number)`

ページ中のnumber番目のフォームを副手順でfield()や click()で呼び出す際のターゲットとして選択します。返り値も選択されたフォームです。選択されたものが存在しない場合には、ワーニングを出し、undefを返します。フォームは1番からインデックスが付けられるので最初のフォームは0ではなく、1です。

$mech->`form_name($name)`

フォームを名前で選択します。ページ上にその名前のフォームが複数ある時は、そのうち最初のものが選択され、ワーニングが生成されます。通常はフォームそれ自体を、見つからなかった時にはundefを返します。

この機能はlibwww-perl 5.69以降を必要としますのでご注意ください。

$mech->field( $name, $value, $number )

$mech->field( $name, \@values, $number )

フィールド名を受け取り、指定された値をそこにセットします。これは現在のフォーム（form()で設定されたものか、デフォルトであるページ内の最初のフォーム）に適用されます。

オプションの$numberパラメータは、2つ以上の同じ名前のフィールドがある時に、それらを区別するのに使われます。フィールドは1から番号がふられます。

$mech->set_fields( $name => $value ... )

このメソッドはフォームの複数のフィールドを設定します。これはフィールド名と値のペアのリストを引数に取ります。もし同じ名前のフィールドが複数あれば、そのうち最初に見つかったものに値がセットされます。この複製されたフィールドのいずれかを選択したいときは、値として、値と番号の 2つの要素をもつ無名配列を使用します。

        # set the second foo field
        $mech->set_fields( $name => [ 'foo', 2 ] ) ;

フィールドは1から番号がふられます。

これは現在のフォーム（form()で設定されたものか、デフォルトであるページ内の最初のフォーム）に適用されます。

$mech->set_visible( @criteria )

このメソッドはフォームフィールドを、そのフィールド名を知る必要なくセットします。したがって、もしユーザー名とパスワードを要求するログイン画面があるなら、そのフィールド名を知るためにフォームを取得してソースから調査する（あるいはWWW::Mechanizeといっしょにインストールされる mech-dumpを使う）必要はありません; こう命じるだけで

    $mech->set_visible( $username, $password ) ;

これにしたがって、1番目と2番目のフィールドがセットされます。このメソッドは、可視（visible）フィールドのみに働くので、set_visibleと呼ばれます; 不可視（hidden）のフォームインプットは無視されます。フィールドの順番はHTMLソース中に出てくる順番と同じで、多くの場合はページ上で見える順番と同じですが、テーブルを使ったクリエイティブなデザインでは異なることがあることは警告しておきます。

@criteriaの個々の要素はフィールド値またはフィールド指定値です。フィールド値はスカラです。フィールド指定値では値をセットしたいフィールドのタイプを指定でき、二つの要素をもつ配列リファレンスで表わされます。したがって、最初のラジオボタンを次のように指定できます

    $mech->set_visible( [ radio => "KCRW" ] ) ;

フィールド値とフィールド指定値は混在させることができ、したがって

    $mech->set_visible( "fred", "secret", [ option => "Checking" ] ) ;

は1、2番目のフィールドを``fred''と``secret''に、そして次のOPTION メニューフィールドを``Checking''にセットします。

フィールド指定値のタイプには以下を使用できます: ``text''や``password''、 ``hidden'',``textarea''、``file''、``image''、``submit''、``radio''、``checkbox''、 ``option''。

$mech->tick( $name, $value [, $set] )

現在のフォーム中の、その名前と値を持つ最初のチェックボックスに '印を付け(Ticks)' ます。その値を持つ名前月のチェックボックスがない時は dieします。オプションの三番目の引数でFalseの値を渡すと、チェックボックスは印がはずされます。

$mech->untick($name, $value)

チェックボックスの印をはずします。tick($name,$value,undef)の短い書き方です。

フォーム送信メソッド

$mech->click( $button [, $x, $y] )

ボタンをクリックする効果を持ちます。最初の引数は、クリックするボタンの名前です。2番目と3番目の（オプションの）引数ではクリックする(x,y) 座標を指定できます。

フォーム上にボタンが一つしかなければ、引数なしで$mech->click()とするだけで、そのボタンをクリックしたことになります。

the HTTP::Response manpageオブジェクトを返します。

$mech->click_button( ... )

フォーム上の名前、値、またはインデックスで指定されたボタンをクリックする効果をもちます。引数はキーと値のペアです。一つの名前、番号、または値だけを指定しなければいけません。

TODO: この関数はテストされていません。

name => name

name

number => n

value => value

value

x => x =item * y => y

$mech->select($name, $value)

$mech->select($name, \@values)

selectフィールド名を与えると、その値を指定された値にセットします。フィールドが<複数選択>ではなく、$valueが配列の時は、その最後の値がセットされます。これは現在のフォーム（form()メソッドでセットされたものか、デフォルトではページの最初のフォーム）に適用されます。

$mech->`submit()`

ボタンをクリックしないまま、そのページをsubmitします。実際には、どのボタンもクリックされなかったことになります。

これは$mech->click("submit")の別名として使用されてきましたが、今後、いずれかのバージョンでなくなるでしょう。

$mech->submit_form( ... )

このメソッドは、直前に取得したページのフォームを選択し、フィールドを埋め、それをsubmitするためのものです。これはform_number/form_name、 set_fields、clickメソッドを一つの高レベルの呼び出しに結合したものです。これの引数はkey/valueの組み合わせのリストで、そのいずれもオプションです。

form_number => n

form_number()

form_name => name

name

form_name()

fields => fields

fields

set_fields()

button => button

button

click()

x => x, y => y

click()

フォームが選択されていない時は、最初に見つかったフォームが使用されます。

buttonが渡されなかった時は、代わりにsubmit()メソッドが使われます。

the HTTP::Response manpageオブジェクトを返します。

ステータスメソッド

$mech->`success()`

最後のリクエストが成功したか否かをtrue(1)かfalse(0)で返します。まだリクエストを実行していなければ、falseを返します。

これは$mech->res->is_successをラップする便利な関数です。

$mech->`uri()`

現在のURIを返します。

$mech->`response()` / $mech->`res()`

現在のレスポンスをthe HTTP::Response manpageオブジェクトとして返します。

$mech->response()の短縮形です。

$mech->`status()`

レスポンス中のHTTPステータスコードを返します。

$mech->`ct()`

レスポンスのコンテントタイプを返します。

$mech->`base()`

現在のレスポンスのベースURIを返します。

$mech->`content()`

レスポンスのコンテントを返します。

$mech->`forms()`

リストコンテキストで呼ばれたときは、最後に取得したページ内で見つかったフォームのリストを返します。スカラーコンテキストのときは、これらのフォームの配列リファレンスを返します。これで返されるフォームはいずれも the HTML::Form manpageオブジェクトです。

$mech->`current_form()`

現在のフォームをthe HTML::Form manpageオブジェクトとして返します。私は form()が既に存在してcurrent_formがセットされている場合を除いてはこちらのform()を呼んでいます。

$mech->`links()`

リストコンテキストで呼ばれたときは、最後に取得したページ内で見つかったリンクのリストを返します。スカラーコンテキストのときは、これらのリンクの配列リファレンスを返します。これで返されるリンクはいずれも the WWW::Mechanize::Link manpageオブジェクトです。

$mech->`is_html()`

現在のコンテントがHTMLか否かをHTTPヘッダーを元に判断して、trueまたは falseを返します。

$mech->`title()`

the HTML::HeadParser manpageの解析結果を元に、<TITLE>タグの内容を返します。コンテントがHTMLではない場合はundefを返します。

コンテントハンドリングメソッド

$mech->`find_link()`

このメソッドは現在取得されているページ内のリンクを検索します。これはそのリンクについて記述しているthe WWW::Mechanize::Link manpageオブジェクトを返します。（きっとURLの記述より、こちらに魅力を覚えるでしょう。）リンクが見つからなかったときにはundefを返します。

URL部分を取り出し、get()メソッドに渡すことができます。もしこれをしたいのであれば、直接follow_link()メソッドを呼ぶのも良いでしょう。これは、自動的にget()を実行します。

<FRAME SRC="...">タグはHTMLとして解析され、リンクとして扱われますので、このメソッドを使えることを覚えておいてください。

以下のkey/valueの組み合わせを一つまたは複数渡すことで、リンクを選択することができます:

text => string および text_regex => regex

text

string

    $mech->find_link( text => "download" );

text_regexは、regexに該当するテキストのリンクにマッチします。大文字小文字を問わず、``download''というテキストが含まれるリンクを選択するには、以下のようにします

    $mech->find_link( text_regex => qr/download/i );

ページのリンクから抽出されたテキストはトリムされることに注意してください。<a> foo </a>は'foo'として保持され、先頭および末尾の空白の検索は失敗します。

url => string および url_regex => regex

string

regex

foo/bar.html

url_abs => string および url_abs_regex => regex

string

regex

name => string および name_regex => regex

string

regex

tag => string および tag_regex => regex

string

regex

tag_regex

    $mech->find_link( tag_regex => qr/^(a|img)$/;

n => number

nパラメータは、上述の他のパラメータと番号を指定するために組み合わせることができます。たとえば、text => "download", n => 3 では``download''というテキストに一致する3番目のリンクが検索されます。

nが指定されなかった場合、デフォルトは1です。したがって、もし一切パラメータを指定しなかった場合には、このメソッドはデフォルトでページ中の最初のリンクを検索します。

複数のテキストまたはURLパラメータを指定でき、これらはすべてand条件として扱われることを覚えておいてください。例えば、テキストが``News''で、 URLに``cnn.com''を含む最初のリンクを探すには、以下のようにします:

    $mech->find_link( text => "News", url_regex => qr/cnn\.com/ );

$mech->`find_link()` : link format

$self->content中のリンクに対応するthe WWW::Mechanize::Link manpage オブジェクトをすべて含んだ配列リファレンスが返り値です。

リンクは、以下から取得されます:

<A HREF=...>
<AREA HREF=...>
<FRAME SRC=...>
<IFRAME SRC=...>

$mech->find_all_links( ... )

判定基準にマッチするすべてのリンクを返します。このメソッドへのリンクの判定基準の指定方法は、find_link()と同じです。すべてのリンクは the WWW::Mechanize::Link manpageとして返されます。

リストコンテキストでは、find_all_links()はリンクのリストを返します。そうでなければ、リンクのリストへのリファレンスを返します。

find_all_links()をパラメータなしで呼ぶと、ページ中のすべてのリンクが返されます。

その他のメソッド

$mech->add_header( name => $value [, name => $value... ] )

エージェントにHTTPリクエスト時に追加または削除するhttpヘッダーを設定します。

    $mech->add_header( Encoding => 'text/klingon' );

もしvalueがundefであれば、そのヘッダーは以降のリクエストでは削除されます。例えば、Refererヘッダーをもう送らないようにするには:

    $mech->add_header( Referer => undef );

もしヘッダーを削除したいのであれば、delete_headerを使います。

追加された名前/値の組み合わせの個数を返します。

NOTE: このメソッドは1.00以前のWWW::Mechanizeとは異なります。以前は、ヘッダーはオブジェクトインスタンスのメンバーではなく、パッケージのハッシュに保持されました。add_header()の呼出しは、仮にそのオブジェクトがすぐになくなる場合でも、全てのWWW::Mechanizeオブジェクトのヘッダーを変更しました。

$mech->delete_header( name [, name ... ] )

Removes HTTP headers from the agent's list of special headers. For instance, you might need to do something like:

    # Don't send a Referer for this URL
    $mech->add_header( Referer => undef );

    # Get the URL
    $mech->get( $url );

    # Back to the default behavior
    $mech->delete_header( 'Referer' );

$mech->`quiet(true/false)`

画面へのワーニングを抑制することができます。

    $mech->quiet(0); # ワーニングを有効にします (デフォルト)
    $mech->quiet(1); # ワーニングを無効にします
    $mech->quiet();  # 現在のquiet設定状態を返します

LWP::UserAgentメソッドのオーバーライド

$mech->`redirect_ok()`

the LWP::UserAgent manpageのredirect_ok()をオーバーライドしたバージョンです。このメソッドはリダイレクションを追跡すべきか否かを判定するために使われます。

$mech->request( $request [, $arg [, $size]])

the LWP::UserAgent manpageのrequest()をオーバーライドしたバージョンです。現在のリクエストを実行します。通常は、WWW::Mechanizeを使っていれば、このようなレベルで作業し様とはまったく思わないでしょうから、こうすべきでしょう

$requestが修正されていることは覚えておいてください。

the HTTP::Response manpageオブジェクトを返します。

$mech->update_html( $html )

mechが見つけたHTMLを置き換えることができます。リンクやフォームを更新します。

もし不恰好な出力をされたページを持っており、更新する気があるというのであればリンクは正しい形で出てくるでしょう:

    my $html = $mech->content;
    $html =~ s[</option>.?.?.?</td>][</option></select></td>]isg;
    $mech->update_html( $html );

$mech->`_parse_html()`

HTMLドキュメントから得られるフォームとリンクを初期化する内部メソッドです。もしサブクラスでこれをオーバーライドしたり、複数回これを呼び出したくなったら、どうぞそうしてください。

$mech->_modify_request( $req )

ずたずたに切り裂かれた内部ヘッダによってリクエストを編集します。

$mech->`_make_request()`

the WWW::Mechanize::Cached manpageのように、サブクラスでリクエストを中断させるのに便利なメソッドです。

使用が推奨されないメソッド

このメソッドはより正しく柔軟なメソッドで置き換えられています。そちら代わりにお使いください。

$mech->`follow($string|$num)`

非推奨になっており、より柔軟なfollow_link()を使うことが勧められます。

リンクを追跡します。文字列を与えれば、そのテキストがこの文字列にマッチする最初のリンクが追跡されます。番号を与えれば、ページ中の $num番目のリンクになります。リンクは0から始まることに注意してください。

ページ中にリンクが見つかればtrueを、そうでなければundefを返します。

$mech->`form($number|$name)`

非推奨になっており、form_name()またはform_number()を使うことが勧められます。

渡されたのが数字だけの文字列か否かによって、フォームを番号または名前で選択します。これは、もし数字だけの名前をもつフォームがあった場合に、このメソッドは正しく動かないかも知れないことを意味しています。

内部使用限定のメソッド

これらのメソッドは内部でのみ使われます。これらについて知る必要は多分ないでしょう。

$mech->`_reset_page()`

ページを解析した際のガラクタのような内部フィールドをリセットします。

$mech->`_extract_links()`

Webページの今テントからリンクを抽出するもので、the WWW::Mechanize::Link manpage の{links}プロパティを一般化します。

$mech->`_push_page_stack()` / $mech->`_pop_page_stack()`

エージェントは訪れたページをスタックしており、BACKの際など必要になった時にはこれで取り出します。

現在のページは新しいページを取得する前にスタックに追加されなければいけませんし、BACKが発生した際にはスタックから取り出されなければいけません。

どちらも引数を与えられても、$mechオブジェクトを操作します。

warn( @messages )

Fatalでない問題と診断用のための、中心となるワーニングメソッドです。デフォルトではCORE::warnを呼びますが、コンストラクタでonwarnをセットすることで上書きできます。

die( @messages )

中心となるエラーメソッドです。デフォルトではCORE::dieを呼びますが、コンストラクタでonerrorをセットすることで上書きできます。

この他のドキュメント

Spidering Hacks, by Kevin Hemenway and Tara Calishain

O'Reilly(http://www.oreilly.com/catalog/spiderhks/)刊の Spidering Hacksはscreen-scrapingとspideringについてもっと知りたい人にとってすばらしい本です。

この本には6つのMechハックおよびMechの派生物があります:

#21 WWW::Mechanize 101
#22 Scraping with WWW::Mechanize
#36 Downloading Images from Webshots
#44 Archiving Yahoo! Groups Messages with WWW::Yahoo::Groups
#64 Super Author Searching
#73 Scraping TV Listings

この本はSlashdotで積極的にレビューされています: http://books.slashdot.org/article.pl

Web上のリソース

WWW::Mechanize Development mailing list

http://sourceforge.net/mail/

LWP mailing list

http://lists.perl.org/showlist.cgi

the WWW::Mechanize::Examples manpage

http://www.perl.com/pub/a/2003/01/22/mechanize.html

http://www.stonehenge.com/merlyn/LinuxMag/col47.html

find_link()

http://www.perladvent.org/2002/16th/

http://www.linux-magazin.de/Artikel/ausgabe/2004/03/perl/perl.html

Linux Magazin

the WWW::Mechanize::Shell manpage

その他のMechanizeを使用するモジュール

以下はMechanizeを使用しているかサブクラスになっているモジュールです。他にあれば教えてください:

the WWW::Bugzilla manpage
the WWW::Google::Groups manpage
the WWW::Mechanize::Cached manpage
the WWW::Mechanize::FormFiller manpage
the WWW::Mechanize::Shell manpage
the WWW::Mechanize::Sleepy manpage
the WWW::Mechanize::SpamCop manpage
the WWW::Mechanize::Timed manpage
the WWW::SourceForge manpage
the WWW::Yahoo::Groups manpage

要望とバグ

要望や示唆、バグ（ヤバッ！）は http://rt.cpan.org/ のRTバグトラッキングシステムか、 bug-WWW-Mechanize@rt.cpan.org へのemailで報告してください。これは私が追跡するのを簡単にしてくれます。

http://rt.cpan.org/NoAuth/Bugs.html はMechanize へのRTキューです。あなたのバグが既に報告されていないか見るにはこちらをチェックしてください。

Author

Artistic Licenseに基づきリリースされています。 Kirrily Robertのすばらしいthe WWW::Automate manpageパッケージをベースにしました。